group = "com.example.analytics_sdk"
version = "1.0-SNAPSHOT"

// Flutter plugins are built within the host application's Gradle process.
// Do not pin AGP or Kotlin versions here: Flutter 3.0 hosts still use
// Gradle 6 / AGP 4, while newer hosts use AGP 8.
rootProject.allprojects {
    repositories {
        google()
        mavenCentral()
        maven { url 'https://jitpack.io' }
        maven { url 'https://developer.huawei.com/repo/' }
        maven { url 'https://developer.honor.com/repo/' }
    }
}

apply plugin: "com.android.library"
apply plugin: "kotlin-android"

android {
    if (project.android.hasProperty("namespace")) {
        namespace = "com.example.analytics_sdk"
    }

    // AGP 4.x understands compileSdkVersion; AGP 7/8 retains it as a
    // compatible (deprecated) alias.
    compileSdkVersion 34

    compileOptions {
        sourceCompatibility = JavaVersion.VERSION_1_8
        targetCompatibility = JavaVersion.VERSION_1_8
    }

    kotlinOptions {
        jvmTarget = "1.8"
    }

    sourceSets {
        main.java.srcDirs += "src/main/kotlin"
        test.java.srcDirs += "src/test/kotlin"
    }

    defaultConfig {
        minSdkVersion 21
    }

    testOptions {
        unitTests.all {
            useJUnitPlatform()

            testLogging {
                events "passed", "skipped", "failed", "standardOut", "standardError"
                outputs.upToDateWhen {false}
                showStandardStreams = true
            }
        }
    }
}

dependencies {
    testImplementation("org.jetbrains.kotlin:kotlin-test")
    testImplementation("org.mockito:mockito-core:5.0.0")
    implementation 'com.github.gzu-liyujiang:Android_CN_OAID:4.2.16'
}